If函數是 Excel 中使用特別多的函數之一，它用于邏輯判斷；Excel If函數共有三個參數，第一個為條件，二三個為返回值，如果條件為真，返回第二個參數，否則返回第三個參數。

If函數可以嵌套，并且在一個If函數中最多能嵌套 64 個 If，以實現組合多個條件。除用嵌套組合多個條件外，還可以用And函數（或 *）組合表示“與”關系的多個條件、用OR函數（或 +）組合表示“或”關系的多個條件；另外，還能用數組作為If函數的條件，這種情況常與別的函數組合使用，例如與VLookUP函數組合使用。

一、Excel If函數語法

1、表達式：IF(Logical_Test, [Value_If_True], [Value_If_False])

中文表達式：如果（條件，[條件為真返回值]，[條件為假返回值]）

2、說明：

A、Logical_Test 為必選項，[Value_If_True] 和 [Value_If_False] 為可選項，可選項可以省略，且必須用 [] 括起來。若省略[Value_If_True] 和 [Value_If_False]，必須在 Logical_Test 后加逗號，否則公式錯誤。

B、If函數最多可以嵌套 64 個 If，但盡量少嵌套，一方面便于閱讀，另一方面執(zhí)行效率也高一些。

C、If 可以與數組組合使用，如果把數組作為 If 的參數，執(zhí)行時，將依次取出數組的每一個元素進行計算。

二、Excel If函數基本使用實例

（一）參數只有一個條件的實例

1、選中 G2 單元格，輸入公式 =if(F2>500,)，按回車，返回 FALSE；雙擊 G2 單元格，把大于號改為小于號，按回車，返回 0；操作過程步驟，如圖1所示：

圖1

2、當If函數只有一個條件時，條件后不能少逗號，如演示中的公式 =if(F2>500,)；當條件 F2>500 為假時，返回 False；當條件 F2<500 為真時，返回 0。

（二）有兩個與三個參數的實例

1、選中 G2 單元格，把公式 =IF(F2>=600,"達標") 復制到 G2，按回車，返回 FALSE；雙擊 G2，把公式改為 =IF(F2>=600,"達標","不達標")，按回車，返回“不達標”；再次選中 G2，把鼠標移到 G2 右下角的單元格填充柄上，鼠標變?yōu)榧犹柡�，雙擊左鍵，則返回剩余服裝銷量評定結果；操作過程步驟，如圖2所示：

圖2

2、公式 =IF(F2>=600,"達標") 省略了最后一個參數，第二個參數后不用加逗號，與只有第一個參數時要加逗號不同；當條件 F2>=600 為假時，由于省略了條件為假時的返回參數，因此用 False 代替。當補充第三個參數后，當條件 F2>=600 為假時，返回第三個參數，即返回“不達標”。

三、Excel If函數多條件嵌套使用實例

（一）嵌套一個條件

1、假如設定服裝銷量大于等于 600 為達標，否則不達標，現在要求找出銷量達標的女裝。選中 G2 單元格，把公式 =IF(C2="女裝",IF(F2>=600,"達標","不達標"),"不達標") 復制到 G2，按回車，返回“不達標”；再次選中 G2，把鼠標移到 G2 右下角的單元格填充柄上，鼠標變?yōu)榧犹柡�，雙擊左鍵，則返回剩余服裝的評定；操作過程步驟，如圖3所示：

圖3

2、公式說明：

A、公式 =IF(C2="女裝",IF(F2>=600,"達標","不達標"),"不達標") 嵌套了一個 If，執(zhí)行過程為：先取外層 If 的條件 C2="女裝" 來判斷，如果為真，則執(zhí)行嵌套的 IF(F2>=600,"達標","不達標")；否則返回外層 If 的"不達標"，即返回公式最后的"不達標"。

B、執(zhí)行嵌套的 IF(F2>=600,"達標","不達標") 時，首先取條件 F2>=600 出來，如果為真，返回“達標”，否則返回“不達標”。

(二）嵌套兩個條件

1、假如要找出銷量大于等于 600、價格小于 70 的女裝，符合條件返回“達標”，否則返回“不達標”。選中 G2 單元格，把公式 =IF(C2="女裝",IF(F2>=600,IF(E2<70,"達標","不達標"),"不達標"),"不達標") 復制到 G2，按回車，返回“不達標”；同樣用雙擊單元格填充柄的方法返回其它服裝是否達標；操作過程步驟，如圖4所示：

圖4

2、公式說明

A、公式 =IF(C2="女裝",IF(F2>=600,IF(E2<70,"達標","不達標"),"不達標"),"不達標") 嵌套了兩個 If；公式執(zhí)行時，最先取出最外層If 的條件 C2="女裝"，如果成立，則執(zhí)行第一個嵌套的 If，即 IF(F2>=600,IF(E2<70,"達標","不達標"),"不達標")；否則返回最外層 If 的“不達標”。

B、執(zhí)行第一個嵌套的 If 時，同樣先取出它的條件 F2>=600，如果成立，則執(zhí)行第二個嵌套的 If，即 IF(E2<70,"達標","不達標")；否則返回第一個嵌套的“不達標”。

C、執(zhí)行第二個嵌套的 If 時，也先取出它的條件 E2<70，如果成立，返回“達標”，否則返回“不達標”；如果嵌套有更多的 If，同樣是按此順序執(zhí)行。

四、Excel If函數用 And(*) 或 OR(+) 組合多個條件的使用實例

（一）用 And(*) 組合多個條件

1、同樣以找出銷量大于等于 600、價格小于 70 的女裝，符合條件返回“達標”，否則返回“不達標”為例。選中 G2 單元格，把公式=IF(AND(C2="女裝",F2>=600,E2<70),"達標","不達標") 復制到 G2，按回車，返回“不達標”；同樣用雙擊單元格填充柄的方法返回剩余服裝的評定。把 G2:G10 的內容刪除，雙擊 G2，把公式 =IF((C2="女裝")*(F2>=600)*(E2<70),"達標","不達標") 復制到 G2，按回車，返回“不達標”，也用雙擊單元格填充柄的方法返回剩余服裝的評定，兩個公式返回的結果一致；操作過程步驟，如圖5所示：

圖5

2、公式說明

1、公式 =IF(AND(C2="女裝",F2>=600,E2<70),"達標","不達標") 的條件為 AND(C2="女裝",F2>=600,E2<70)，即用And函數組合三個條件，每個條件之間用逗隔開，只有三個條件都為真時，And才返回真，否則返回假；當 And 返回真時，If 返回“達標”，否則 If 返回“不達標”。

2、除可用 And 組合表示“與”條件外，也可以用星號 * 組合，每個條件要用括號括起來，條件與條件之間用 * 連接，如演示中的條件(C2="女裝")*(F2>=600)*(E2<70)，它等同于 AND(C2="女裝",F2>=600,E2<70)。

（二）用 OR(+) 組合多個條件

1、假如要標出銷量小于 400 或大于等于 800 或價格大于 90 的服裝。選中 G2  單元格，把公式 =IF(OR(F2<400,F2>=800,E2>90),"滿足","不滿足") 復制到 G2，按回車，返回“滿足”；用雙擊單元格填充柄的方法返回剩余服裝是否滿足條件；操作過程步驟，如圖6所示：

圖6

2、公式說明

公式 =IF(OR(F2<400,F2>=800,E2>90),"滿足","不滿足") 的條件為 OR(F2<400,F2>=800,E2>90)，它是“或”的關系，即只要滿足一個條件就返回真；如果 OR(F2<400,F2>=800,E2>90) 返回真，If 返回“滿足”，否則 If 返回“不滿足”。

3、用加號 + 代替 OR 組合“或”關系的條件

把公式 =IF(OR(F2<400,F2>=800,E2>90),"滿足","不滿足")

用加號 + 代替 OR 變?yōu)椋?/span>

=IF((F2<400)+(F2>=800)+(E2>90),"滿足","不滿足")

這兩個公式返回的結果一樣。